lexer.lex

Go to the documentation of this file.

/*
 *  Copyright 2007 Martin von Gagern
 *
 *
 *  This file is part of mqn2mps.
 *
 *  mqn2mps is free software; you can redistribute it and/or modify
 *  it under the terms of the GNU General Public License as published by
 *  the Free Software Foundation; either version 3 of the License, or
 *  (at your option) any later version.
 *
 *  mqn2mps is distributed in the hope that it will be useful,
 *  but WITHOUT ANY WARRANTY; without even the implied warranty of
 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 *  GNU General Public License for more details.
 *
 *  You should have received a copy of the GNU General Public License
 *  along with this program.  If not, see <http://www.gnu.org/licenses/>.
 */


%{
#include <string>
#include <limits>
#include <cstdlib>
#include "driver.hh"
#include "parser.hh"
#include "lexer.hh"

#define yyterminate() return token::END

#define YY_USER_ACTION yylloc->columns (YYLeng());

#ifdef YY_DECL
#undef YY_DECL
#endif
#define YY_DECL                                     \
yy::parser::token_type                              \
yy::lexer::yylex(yy::parser::semantic_type* yylval, \
                 yy::parser::location_type* yylloc)
%}

%option noyywrap nounput batch debug c++ yyclass="lexer"

%x QS

ws   [ \t\f]
nl   \r\n|\n|\r
word [a-zA-Z_][a-zA-Z_0-9]*

%%

  /**
   * @cond LEXER
   */

%{
yylloc->step();
typedef yy::parser::token token;
std::string strbuf;
%}

{ws}+           yylloc->step();
{nl}            yylloc->lines(1); yylloc->step();

[*/,{};=+-]     return yy::parser::token_type (YYText()[0]);

[0-9]+          {
  errno = 0;
  long n = strtol(YYText(), NULL, 10);
  if (n < 0 || n > std::numeric_limits<int>::max() || errno == ERANGE) {
    theDriver.error(*yylloc, "integer is out of range");
  }
  yylval->i = n;
  return token::INT;
}

\"\*\"          return yy::parser::token_type ('*');

{word}          yylval->s = new std::string(YYText()); return token::WORD;

\"              strbuf=""; BEGIN(QS);
<QS>[^"\r\n]+   strbuf += YYText();
<QS>{nl}        strbuf += "\n"; yylloc->lines(1);
<QS>\"          {
  yylval->s = new std::string(strbuf);
  BEGIN(INITIAL);
  return token::QSTR;
}

.               theDriver.error(*yylloc, "invalid character");


  /**
   * @endcond 
   */

%%

namespace yy {

  lexer::lexer(driver &d, std::istream* in, std::ostream* out)
    : yyFlexLexer(in, out), theDriver(d) {
  }

  lexer::~lexer() {
  }

  void lexer::LexerError(const char* msg) {
    theDriver.error(msg);
    exit(YY_EXIT_FAILURE);
  }

}

---